TAL.VISS.SETT-funksjonen

Returnerer kor mange celler som oppfyller kriteria i fleire omrÄde.

tip

Denne funksjonen er tilgjengeleg sidan LibreOffice4.0


Syntaks

TAL.VISS.SETT(OmrÄde1; Kriterium1[; OmrÄde2; Kriterium2 [; ...]])

OmrĂ„de1 – nĂždvendig argument. Dette kan vera eit celleomrĂ„de, namnet pĂ„ eit namngjeve omrĂ„de eller etiketten pĂ„ ei rad eller ein kolonne som inneheld verdiar som vert brukte for Ă„ telja og Ă„ finna det tilsvarande kriteriet.

Kriterium1 mÄ ha eit argument. Eit strenguttrykk som representerer eit logisk vilkÄr eller ein cellereferanse til eit slikt uttrykk. Uttrykket kan innehalda tekst, tal, regulÊre uttrykk eller jokerteikn (viss det er opna for desse i innstillingane for utrekningane).

OmrĂ„de2 – Valfri. OmrĂ„de2 og alle dei fĂžlgjande tyder det same som OmrĂ„de1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfþlgjande betyr det same som Kriterium1.

SĂžkinga har stĂžtte fpr jokerteikn eller regulĂŠre uttrykk. Med regulĂŠre uttrykk slĂ„tt pĂ„, kan du for eksempel skriva inn «all» for Ă„ finna den fĂžrste staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal sĂžkja etter ein tekst som ogsĂ„ er eit regulĂŠrt uttrykk, mĂ„ du skriva bakoverstrek (\) framfĂžre kvart teikn eller du mĂ„ lukka inn teksten mellom «\Q» og «\E». Du kan slĂ„ den automatiske evalueringa av jokerteikn og regulĂŠre uttrykk av eller pĂ„ frĂ„ i → LibreOffice Calc → Rekn ut.

warning

NÄr du brukar funksjonar der eitt eller fleire argument er sÞkjekriterium som representerer eit regulÊrt uttrykk, vert det fÞrst prÞvd Ä konvertere strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og sÄ vidare. Viss dette gÄr bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. NÄr du brukar eit sprÄk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulÊre uttrykk fungera. For Ä tvinga evalueringa av det regulÊre uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


OmrÄde1, OmrÄde2, 
 og Kriterium1, Kriterium2, ... mÄ ha same storleik, elles returnerer funksjonen feil:502 - Ugyldig argument.

note

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frÄ den tilsvarande cella i det gjevne Funksjons_omrÄde tatt med i utrekningane.


Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieomrÄde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

Merknadsikon

Denne funksjonen hĂžyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)


Eksempel

Studer denne tabellen

A

B

C

1

Produktnamn

Sal

Inntekt

2

blyant

20

65

3

penn

35

85

4

notisbok

20

190

5

bok

17

180

6

penal

ikkje

ikkje


warning

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.


Enkel bruk

=TAL.VISS.SETT(B2:B6;">=20")

Tel kor mange rader i omrÄdet B2:B6 som har verdiar stÞrre enn eller lik 20. Returnerer 3 fordi den femte og sjette rada ikkje oppfyller kriteria.

=TAL.VISS.SETT(B2:B6;">=20";C2:C6;">70")

Tel kor mange rader i omrÄdet C2:C6 som samstundes har verdiar stÞrre enn 70 og verdiar stÞrre enn eller lik 20 i omrÄdet B2:B6. Returnerer 2 fordi den andre, femte og sjette rada ikkje oppfyller minst eitt kriterium.

Bruka regulĂŠre uttrykk og nĂžsta funksjonar

=TAL.VISS.SETT(B2:B6;"[:alpha:]*")

Tel kor mange rader i omrÄdet B2:B6 som inneheld alfabetsymbol. Returnerer 1 fordi berre den sjette rada oppfyller kriteriet.

=TAL.VISS.SETT(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Tel kor mange rader det er i omrÄdet B2:B6. Reknar ikkje med rader som inneheld maksimums- og minimumsverdien i dette omrÄdet. Returnerer 2 fordi den tedje, femte og sjette rada ikkje oppfyller minst eitt kriterium.

=TAL.VISS.SETT(A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Tel kor mange rader som samsvarar med alle cellene i omrÄdet A2:A6 som byrjar med «pen» og alle cellene i omrÄdet B2:B6 unntatt dei som inneheld minimum. Returnerer 1 fordi berre den andre rada oppfyller alle kriteria.

Referanse til ei celle som kriterium

Dersom du Ăžnskjer Ă„ lett kunna endra eit kriterium, kan du skrive dette inn i ei eige celle og bruke ein referanse til denne cella som kriterium i funksjonen TAL.VISS.SETT. For eksempel kan funksjonen ovanfor skrivast slik:

=TAL.VISS.SETT(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Viss E2 = pen vil funksjonen returnere 1 fordi lenkja til cella er bytt ut med innhaldet og sÄleis verkar som funksjonen ovanfor.